Contact Us 1-800-596-4880
  1. Homepage
  2. MuleSoft Terraform Provider
  3. Resources

  4. MCP and AI Agent Resources

MCP and AI Agent Resources

Use these resources to manage MCP servers, MCP bridges, and AI agent resources.

anypoint_mcp_server

Use the anypoint_mcp_server resource to create and manage MCP servers in Anypoint API Manager.

An MCP server represents an MCP server specification deployed to an Omni Gateway target with routing rules and upstream backends.

Connected App: This resource requires a standard connected app (client credentials). An admin connected app isn’t needed. The connected app must have relevant scopes.

Status after create: After a successful terraform apply the status field is populated from a GET request made immediately after the POST. The platform typically returns status = "active" right away.

upstream_uri vs routing: upstream_uri and routing are mutually exclusive. Use upstream_uri for a single upstream. Only one upstream per route is supported for MCP servers — multi-upstream weighted routing isn’t available.

upstream_id: The computed upstream_id attribute is the server-assigned ID for the first upstream. Reference it in outbound policy upstream_ids to bind policies to this MCP server’s upstream.

Example Usage

Basic MCP server with upstream_uri

resource "anypoint_mcp_server" "example" {
  organization_id = var.organization_id
  environment_id  = var.environment_id
  technology      = "omniGateway"
  instance_label  = "atlassian-mcp-server"

  spec = {
    asset_id = "my-mcp-spec"
    group_id = var.organization_id
    version  = "1.0.0"
  }

  endpoint = {
    deployment_type = "HY"
    base_path       = "mcp1"
  }

  gateway_id   = var.gateway_id
  upstream_uri = "http://example.com"
}

MCP server with explicit routing

resource "anypoint_mcp_server" "advanced" {
  organization_id = var.organization_id
  environment_id  = var.environment_id
  technology      = "omniGateway"
  instance_label  = "enterprise-tools-mcp"

  spec = {
    asset_id = "postman-mcp-server"
    group_id = var.organization_id
    version  = "1.0.0"
  }

  endpoint = {
    deployment_type = "HY"
    base_path       = "mcp-tools"
  }

  gateway_id = var.gateway_id

  routing = [
    {
      upstreams = [
        {
          weight = 100
          uri    = "http://mcp-tools.internal:8080"
        }
      ]
    }
  ]
}

Required Arguments

  • environment_id - The environment ID where the MCP server will be created.

  • spec - (Block) The Exchange asset specification backing this MCP server..

Optional Arguments

  • organization_id - Organization ID. If not provided, the organization ID is inferred from the connected app credentials.

  • technology - The gateway technology. Only omniGateway is currently supported. Defaults to omniGateway.

  • provider_id - The identity provider ID for the MCP server.

  • instance_label - A human-readable label for this MCP server.

  • approval_method - Client approval method. Valid values: manual, automatic. Defaults to null (no approval required).

  • consumer_endpoint - Consumer-facing endpoint URI (the public URL clients use to reach the MCP server). For MCP, this is the proxy URI that clients connect to.

  • upstream_uri - Shorthand for a single-upstream routing configuration. Mutually exclusive with routing.

  • gateway_id - The Omni Gateway UUID. When provided, the deployment block is auto-populated from the Gateway Manager. Mutually exclusive with a full deployment block.

  • endpoint - (Block) Endpoint and proxy configuration..

  • deployment - (Block) Deployment target configuration. Auto-populated when gateway_id is set..

  • routing - (Block List) Routing rules with upstream backends. Mutually exclusive with upstream_uri..

Read-Only Attributes

  • id - The numeric identifier of the MCP server (stored as string for Terraform compatibility).

  • status - The current status of the MCP server.

  • asset_id - The Exchange asset ID (computed from MCP server response).

  • asset_version - The Exchange asset version (computed from MCP server response).

  • product_version - The product version (computed from MCP server response).

  • upstream_id - The server-assigned upstream ID for the first upstream. Use this to reference the upstream in outbound policy upstream_ids.

Nested Schema for spec

  • asset_id - (Required) The Exchange asset ID.

  • group_id - (Required) The Exchange group (organization) ID.

  • version - (Required) The asset version.

Nested Schema for endpoint

  • deployment_type - Deployment type. Valid values: HY (hybrid), CH (CloudHub), RF (Runtime Fabric). Defaults to HY.

  • type - Endpoint protocol type. For MCP servers, this is mcp. Defaults to mcp.

  • base_path - MCP server base path for Omni Gateway (for example, my-mcp-server). The provider constructs the proxy URI as http://0.0.0.0:8081/<base_path>.

  • uri - Direct implementation URI. Mutually exclusive with base_path.

  • response_timeout - Response timeout in milliseconds.

Nested Schema for deployment

  • environment_id - The environment ID for deployment (usually matches the top-level environment_id).

  • type - Deployment type. Valid values: HY, CH, RF. Defaults to HY.

  • expected_status - Expected deployment status. Valid values: deployed, undeployed. Defaults to deployed.

  • overwrite - Whether to overwrite an existing deployment.

  • target_id - The target gateway ID to deploy to.

  • target_name - The target gateway name.

  • gateway_version - The Omni Gateway runtime version.

Nested Schema for routing

  • upstreams - (Required, Block List) Upstream backends for this route. For MCP servers, these are the actual MCP server implementation endpoints..

  • label - A label for this route.

  • rules - (Block) Match conditions for this route..

Nested Schema for routing.rules

  • methods - Pipe-separated HTTP methods (for example, GET, POST|PUT).

  • path - URL path pattern to match (for example, /api/*).

  • host - Host header value to match.

  • headers - (Map) Header key-value pairs to match.

Nested Schema for routing.upstreams

  • uri - (Required) The upstream backend URI. For MCP servers, this is the actual MCP server implementation URI that requests are forwarded to.

  • weight - Traffic weight percentage (0–100). Defaults to 100.

  • label - A label for this upstream.

  • tls_context_id - TLS context for upstream connections. Format: secretGroupId/tlsContextId.

Import

An existing MCP server can be imported using its composite ID: organization_id/environment_id/mcp_server_id.

The mcp_server_id is the numeric ID visible in the Anypoint API Manager URL.

import {
  to = anypoint_mcp_server.imported
  id = "<organization_id>/<environment_id>/<mcp_server_id>"
}

resource "anypoint_mcp_server" "imported" {
  organization_id = "<organization_id>"
  environment_id  = "<environment_id>"
  spec = {
    asset_id = "<mcp_server_asset_id>"
    group_id = "<organization_id>"
    version  = "1.0.0"
  }
}

After adding the import block, run:

# Let Terraform generate the full resource configuration automatically:
terraform plan -generate-config-out=generated.tf

# Or apply the import directly if you have an existing resource block:
terraform apply

Using the CLI (deprecated, Terraform < 1.5)

terraform import anypoint_mcp_server.imported <organization_id>/<environment_id>/<mcp_server_id>

anypoint_agent_instance

Use the anypoint_agent_instance resource to create and manage Agent instances in Anypoint API Manager.

An Agent instance represents an Agent specification deployed to an Omni Gateway target with routing rules and upstream backends.

Connected App: This resource requires a standard connected app (client credentials). An admin connected app isn’t needed. The connected app must have relevant scopes.

Status after create: After a successful terraform apply the status field is populated from a GET request made immediately after the POST. The platform typically returns status = "active" right away. If your Gateway isn’t yet ready, the provider retries the POST up to 5 times with a 20-second backoff before failing.

upstream_uri vs routing: upstream_uri and routing are mutually exclusive. Use upstream_uri for a single upstream — the provider expands it to [{upstreams: [{weight: 100, uri: <value>}]}] automatically. Only one upstream per route is supported; multi-upstream weighted routing isn’t available for Agent instances.

Example Usage

Basic Agent instance with upstream_uri

resource "anypoint_agent_instance" "example" {
  organization_id = var.organization_id
  environment_id  = var.environment_id
  technology      = "omniGateway"
  instance_label  = "customer-support-agent"

  spec = {
    asset_id = "my-agent-spec"
    group_id = var.organization_id
    version  = "1.0.0"
  }

  endpoint = {
    deployment_type = "HY"
    base_path       = "agent/support"
  }

  gateway_id   = var.gateway_id
  upstream_uri = "http://agent-service.internal:8080"
}

Agent instance with explicit routing

resource "anypoint_agent_instance" "advanced" {
  organization_id = var.organization_id
  environment_id  = var.environment_id
  technology      = "omniGateway"
  instance_label  = "sales-agent"

  spec = {
    asset_id = "my-agent-spec"
    group_id = var.organization_id
    version  = "1.0.0"
  }

  endpoint = {
    deployment_type = "HY"
    base_path       = "agent/sales"
  }

  gateway_id = var.gateway_id

  routing = [
    {
      upstreams = [
        {
          weight = 100
          uri    = "http://sales-agent.internal:8080"
        }
      ]
    }
  ]
}

Required Arguments

  • environment_id - The environment ID where the Agent instance will be created.

  • spec - (Block) The Exchange asset specification backing this Agent instance..

Optional Arguments

  • organization_id - Organization ID. If not provided, the organization ID is inferred from the connected app credentials.

  • technology - The gateway technology. Only omniGateway is currently supported. Defaults to omniGateway.

  • provider_id - The identity provider ID for the Agent.

  • instance_label - A human-readable label for this Agent instance.

  • approval_method - Client approval method. Valid values: manual, automatic. Defaults to null (no approval required).

  • consumer_endpoint - Consumer-facing endpoint URI (the public URL clients use to reach the Agent).

  • upstream_uri - Shorthand for a single-upstream routing configuration. Mutually exclusive with routing.

  • gateway_id - The Omni Gateway UUID. When provided, the deployment block is auto-populated from the Gateway Manager. Mutually exclusive with a full deployment block.

  • endpoint - (Block) Endpoint and proxy configuration..

  • deployment - (Block) Deployment target configuration. Auto-populated when gateway_id is set..

  • routing - (Block List) Routing rules with weighted upstream backends. Mutually exclusive with upstream_uri..

Read-Only Attributes

  • id - The numeric identifier of the Agent instance (stored as string for Terraform compatibility).

  • status - The current status of the Agent instance.

  • asset_id - The Exchange asset ID (computed from Agent response).

  • asset_version - The Exchange asset version (computed from Agent response).

  • product_version - The product version (computed from Agent response).

Nested Schema for spec

  • asset_id - (Required) The Exchange asset ID.

  • group_id - (Required) The Exchange group (organization) ID.

  • version - (Required) The asset version.

Nested Schema for endpoint

  • deployment_type - Deployment type. Valid values: HY (hybrid), CH (CloudHub), RF (Runtime Fabric). Defaults to HY.

  • type - Endpoint protocol type. For Agent instances, this is a2a (Agent-to-Agent). Defaults to a2a.

  • base_path - Agent base path for Omni Gateway (for example, my-agent). The provider constructs the proxy URI as http://0.0.0.0:8081/<base_path>.

  • uri - Direct implementation URI. Mutually exclusive with base_path.

  • response_timeout - Response timeout in milliseconds.

Nested Schema for deployment

  • environment_id - The environment ID for deployment (usually matches the top-level environment_id).

  • type - Deployment type. Valid values: HY, CH, RF. Defaults to HY.

  • expected_status - Expected deployment status. Valid values: deployed, undeployed. Defaults to deployed.

  • overwrite - Whether to overwrite an existing deployment.

  • target_id - The target gateway ID to deploy to.

  • target_name - The target gateway name.

  • gateway_version - The Omni Gateway runtime version.

Nested Schema for routing

  • upstreams - (Required, Block List) Weighted upstream backends for this route..

  • label - A label for this route.

  • rules - (Block) Match conditions for this route..

Nested Schema for routing.rules

  • methods - Pipe-separated HTTP methods (for example, GET, POST|PUT).

  • path - URL path pattern to match (for example, /api/*).

  • host - Host header value to match.

  • headers - (Map) Header key-value pairs to match.

Nested Schema for routing.upstreams

  • uri - (Required) The upstream backend URI.

  • weight - Traffic weight percentage (0–100). Defaults to 100.

  • label - A label for this upstream.

  • tls_context_id - TLS context for upstream connections. Format: secretGroupId/tlsContextId.

Import

An existing Agent instance can be imported using its composite ID: organization_id/environment_id/agent_instance_id.

The agent_instance_id is the numeric ID visible in the Anypoint API Manager URL.

import {
  to = anypoint_agent_instance.imported
  id = "<organization_id>/<environment_id>/<agent_instance_id>"
}

resource "anypoint_agent_instance" "imported" {
  organization_id = "<organization_id>"
  environment_id  = "<environment_id>"
  spec = {
    asset_id = "<agent_asset_id>"
    group_id = "<organization_id>"
    version  = "1.0.0"
  }
}

After adding the import block, run:

# Let Terraform generate the full resource configuration automatically:
terraform plan -generate-config-out=generated.tf

# Or apply the import directly if you have an existing resource block:
terraform apply

Using the CLI (deprecated, Terraform < 1.5)

terraform import anypoint_agent_instance.imported <organization_id>/<environment_id>/<agent_instance_id>

anypoint_mcp_bridge

Use the anypoint_mcp_bridge resource to create and manage an MCP bridge in Anypoint API Manager. An MCP bridge generates an MCP server from one or more source REST APIs by publishing a generated Exchange asset, deploying a Flex/Self-Managed Gateway instance, and attaching MCP transcoding policies that map MCP tool calls to REST calls.

Connected App: This resource requires a standard connected app (client credentials). An admin connected app isn’t needed. The connected app must have relevant scopes.

anypoint_mcp_bridge vs anypoint_mcp_server: Use anypoint_mcp_bridge when you want the provider to generate an MCP server from existing REST API specs in Exchange. Use anypoint_mcp_server when you already have an MCP server spec and want to deploy it directly.

Gateway must be running: The target gateway must be connected and running before you apply. If it isn’t, the provider raises a GatewayNotReadyError and retries briefly before failing.

ForceNew fields: environment_id, gateway_id, mcp_asset_name, port, and base_path can’t be changed after creation. Structural changes to source_apis (adding or removing source APIs, or changing label, upstream_uri, asset_id, group_id, version, or tls_context_id) also require replacement. Use terraform apply -replace=<resource_address> to recreate the resource. Tool-level changes within a source API (adding, removing, or editing tools) are applied in place and bump the generated Exchange asset version.

Example Usage

resource "anypoint_mcp_bridge" "example" {
  organization_id = var.organization_id
  environment_id  = var.environment_id
  gateway_id      = var.gateway_id
  mcp_asset_name  = "petstore-mcp-bridge"
  port            = 8081
  base_path       = "petstore"

  source_apis = [
    {
      label        = "petstore-api"
      upstream_uri = "https://sandbox.example.com/petstore/v1"
      asset_id     = "petstore-rest-api"
      version      = "1.0.0"

      tools = [
        {
          method       = "GET"
          path         = "/pets"
          description  = "List all pets"
          query_params = ["limit", "offset"]
        },
        {
          method   = "POST"
          path     = "/pets"
          has_body = true
        },
        {
          method = "GET"
          path   = "/pets/{petId}"
        },
      ]
    },
  ]
}

Required Arguments

  • environment_id - The environment ID where the bridge is created. Changing this value forces a new resource.

  • gateway_id - The UUID of the Flex or Self-Managed Gateway to deploy to. Changing this value forces a new resource.

  • mcp_asset_name - The MCP asset name. Becomes the generated Exchange asset name and the instance name. Changing this value forces a new resource.

  • source_apis - (Attributes List) One entry per source REST API. See Nested Schema for source_apis.

Optional Arguments

  • organization_id - Organization ID. If not provided, the organization ID is inferred from connected app credentials.

  • port - (Number) Listener port. Defaults to 8081. Changing this value forces a new resource.

  • base_path - Base path for the MCP server endpoint. Changing this value forces a new resource.

  • instance_label - A label for this bridge instance shown in API Manager. Applied in place.

  • approval_method - Client access approval method. Set to manual to hold client access requests for review before granting access. Applied in place.

  • consumer_endpoint - The public URL clients use to reach the bridge (shown as "Consumer Endpoint" in API Manager). Not derived automatically. A bridge created without this attribute shows an empty consumer endpoint in API Manager. Applied in place.

  • provider_id - The external client provider ID for application authentication. Omit to use Anypoint’s built-in client provider. Applied in place.

Read-Only Attributes

  • id - The numeric API Manager instance ID (stored as a string).

  • asset_id - The generated Exchange asset ID.

  • asset_version - The current version of the generated Exchange asset. Starts at 1.0.0 and bumps on each tool-level update.

  • product_version - The product version of the bridge.

  • consumer_endpoint - The public consumer endpoint. May be null for self-managed Flex Gateway bridges. Use proxy_uri in that case.

  • proxy_uri - The proxy URI (http://0.0.0.0:<port>/<base_path>;).

  • status - The current status of the bridge.

  • technology - Always flexGateway.

  • deployment - (Object) Auto-populated deployment details. See Nested Schema for deployment.

Nested Schema for source_apis

  • label - (Required) Route label and X-UPSTREAM-NAME header value. Must be unique within the bridge.

  • upstream_uri - (Required) The backend base URI for this source API.

  • asset_id - (Required) The Exchange asset ID of the source REST API.

  • version - (Required) The Exchange asset version of the source REST API.

  • tools - (Required, Attributes List) The MCP tools to expose from this source API. See Nested Schema for tools.

  • group_id - The group ID of the source Exchange asset. Defaults to organization_id.

  • tls_context_id - TLS context to use when the backend is HTTPS and the gateway must trust its certificate. Format: secretGroupId/tlsContextId (same format as anypoint_mcp_server). Changing this value forces replacement.

Nested Schema for source_apis.tools

  • method - (Required) The HTTP method. Valid values: GET, POST, PUT, PATCH, and DELETE.

  • path - (Required) The API path (for example, /pets/{petId}). Must start with /. Path parameters become required tool inputs.

  • name - The tool name. Defaults to <method>_<slugified_path>.

  • description - A description of the tool shown to the AI agent.

  • query_params - (List of String) Query parameter names to expose as tool inputs.

  • header_params - (List of String) Header parameter names to expose as tool inputs.

  • has_body - Whether the tool accepts a request body. Defaults to false. When true, adds a required body input to the tool.

  • input_schema - (String) A JSON Schema object that replaces the derived input schema for this tool. Use jsonencode({…​}) to pass the schema inline. Without this attribute every property defaults to type string. Set it when you need real types, enums, or constraints on tool inputs. Updating this value republishes the generated Exchange asset and bumps asset_version.

  • http_mapping - (Block) Overrides how tool inputs map to the upstream HTTP request. Omit to use the derived mapping. Each field is independent, omitting one leaves that part derived. Updating this value re-syncs the transcoding policy only and doesn’t bump asset_version. See Nested Schema for http_mapping.

Nested Schema for source_apis.tools.http_mapping

  • query_params - (Block List) Query parameter mappings. See Nested Schema for param mappings.

  • uri_params - (Block List) URI parameter mappings.

  • headers - (Block List) Header mappings.

  • body - (String) Body mapping expression.

Nested Schema for http_mapping Param Entries

  • key - (Required) The upstream parameter name.

  • value - (Required) The tool input name or expression to map to this parameter.

Nested Schema for deployment

  • environment_id - The environment ID of the deployment.

  • type - The deployment type (always HY).

  • expected_status - The expected deployment status.

  • overwrite - Whether the deployment overwrites an existing one.

  • target_id - The target ID of the deployment.

  • target_name - The target name.

  • gateway_version - The gateway version used for the deployment.

Import an Existing MCP Bridge

An existing MCP bridge can be imported using a composite <organization_id>/<environment_id>/<mcp_bridge_id> ID. The mcp_bridge_id is the numeric API Manager instance ID visible in the API Manager URL.

On import, the provider reconstructs source_apis (labels, upstreams, tools) from the live routing and transcoding policies. Tool description values are left null after import. They live only in the generated Exchange asset metadata and don’t cause spurious diffs.

import {
  to = anypoint_mcp_bridge.imported
  id = "<organization_id>/<environment_id>/<mcp_bridge_id>"
}

resource "anypoint_mcp_bridge" "imported" {
  organization_id = "<organization_id>"
  environment_id  = "<environment_id>"
  gateway_id      = "<gateway_id>"
  mcp_asset_name  = "<mcp_asset_name>"
  source_apis     = []
}

After adding the import block, run:

# Let Terraform generate the full resource configuration automatically:
terraform plan -generate-config-out=generated.tf

# Or apply the import directly if you have an existing resource block:
terraform apply

Using the CLI (Deprecated, Terraform < 1.5)

terraform import anypoint_mcp_bridge.imported <organization_id>/<environment_id>/<mcp_bridge_id>

anypoint_mcp_bridge Data Source

Use the anypoint_mcp_bridge data source to read the full details of a single MCP bridge by ID, including reconstructed source APIs and tools.

Tool descriptions: Tool description values are always null when read from this data source. They live only in the generated Exchange asset metadata and aren’t exposed via the API Manager APIs.

Example Usage

data "anypoint_mcp_bridge" "one" {
  organization_id = var.organization_id
  environment_id  = var.environment_id
  id              = "21058094"
}

output "bridge_tools" {
  value = [for s in data.anypoint_mcp_bridge.one.source_apis : {
    label = s.label
    tools = [for t in s.tools : t.name]
  }]
}

Required Arguments

  • id - The numeric API Manager instance ID of the MCP bridge.

  • environment_id - The environment ID.

Optional Arguments

  • organization_id - The organization ID. If not specified, uses the organization from provider credentials.

Read-Only Attributes

  • gateway_id - The UUID of the gateway the bridge is deployed to.

  • port - (Number) The listener port.

  • base_path - The base path.

  • asset_id - The generated Exchange asset ID.

  • asset_version - The current version of the generated Exchange asset.

  • product_version - The product version.

  • group_id - The group ID of the generated asset.

  • technology - Always flexGateway.

  • instance_label - The instance label.

  • status - The current status.

  • consumer_endpoint - The public consumer endpoint. May be null for self-managed Flex Gateway bridges. Use proxy_uri in that case.

  • proxy_uri - The proxy URI (http://0.0.0.0:<port>/<base_path>;).

  • deployment - (Object) Deployment details. See Nested Schema for deployment.

  • source_apis - (List of Object) Reconstructed source APIs and tools. See Nested Schema for source_apis.

Nested Schema for deployment

  • environment_id - The environment ID.

  • type - The deployment type.

  • expected_status - The expected status.

  • target_id - The target ID.

  • target_name - The target name.

  • gateway_version - The gateway version.

Nested Schema for source_apis

  • label - The route label.

  • upstream_uri - The backend base URI.

  • asset_id - The Exchange asset ID.

  • group_id - The Exchange asset group ID.

  • version - The Exchange asset version.

  • tools - (List of Object) The MCP tools.

    • name - The tool name.

    • description - Always null (lives in Exchange asset metadata).

    • method - The HTTP method.

    • path - The API path.

    • query_params - (List of String) Query parameter names.

    • header_params - (List of String) Header parameter names.

    • has_body - Whether the tool accepts a request body.

anypoint_mcp_bridges Data Source

Use the anypoint_mcp_bridges data source to list all MCP bridges in an environment.

Example Usage

data "anypoint_mcp_bridges" "all" {
  organization_id = var.organization_id
  environment_id  = var.environment_id
}

output "bridge_ids" {
  value = [for b in data.anypoint_mcp_bridges.all.bridges : b.id]
}

Required Arguments

  • environment_id - The environment ID.

Optional Arguments

  • organization_id - The organization ID. If not specified, uses the organization from provider credentials.

Read-Only Attributes

  • id - Composite identifier <organization_id>/<environment_id>.

  • bridges - (List of Object) The list of MCP bridges. See Nested Schema for bridges.

Nested Schema for bridges

  • id - The numeric API Manager instance ID.

  • asset_id - The generated Exchange asset ID.

  • asset_version - The current version of the generated Exchange asset.

  • product_version - The product version.

  • group_id - The group ID.

  • technology - Always flexGateway.

  • instance_label - The instance label.

  • status - The current status.

  • endpoint_uri - The public endpoint URI. May be null for self-managed Flex Gateway bridges. Use proxy_uri in that case.

  • proxy_uri - The proxy URI. Fetched per bridge. Null if the per-bridge fetch fails.

anypoint_mcp_tools Data Source

Use the anypoint_mcp_tools data source to read a source REST API’s Exchange spec and generate the tool list automatically. Use the output to populate source_apis[].tools in an anypoint_mcp_bridge resource without hand-writing each tool entry.

Example Usage

data "anypoint_mcp_tools" "petstore" {
  organization_id = var.organization_id
  group_id        = var.organization_id
  asset_id        = "petstore-rest-api"
  version         = "1.0.0"
}

resource "anypoint_mcp_bridge" "example" {
  organization_id = var.organization_id
  environment_id  = var.environment_id
  gateway_id      = var.gateway_id
  mcp_asset_name  = "petstore-mcp-bridge"

  source_apis = [
    {
      label        = "petstore-api"
      upstream_uri = "https://sandbox.example.com/petstore/v1"
      asset_id     = "petstore-rest-api"
      version      = "1.0.0"
      tools        = data.anypoint_mcp_tools.petstore.tools
    },
  ]
}

Required Arguments

  • organization_id - The organization ID.

  • group_id - The group ID of the Exchange asset (usually the same as organization_id).

  • asset_id - The Exchange asset ID of the source REST API.

  • version - The Exchange asset version.

Optional Arguments

  • exclude_methods - (List of String) HTTP methods to exclude from the generated tool list (for example, ["DELETE", "PATCH"]).

  • exclude_tool_names - (List of String) Tool names to exclude from the generated tool list.

Read-Only Attributes

  • tools - (List of Object) The generated tool list. Use this directly as source_apis[].tools in anypoint_mcp_bridge. See Nested Schema for tools.

  • spec_type - The detected spec type of the Exchange asset (for example, oas, raml).

Nested Schema for tools

  • method - The HTTP method.

  • path - The API path.

  • name - The generated tool name.

  • description - The tool description derived from the spec.

  • query_params - (List of String) Query parameter names.

  • header_params - (List of String) Header parameter names.

  • has_body - Whether the operation accepts a request body.